Example 2.2: Predator-prey model (Ch 2, page 27)

Clear["Global`*"]
Off[General::spell1]

System

Parameters

a=1;
b=1;
c=1;
d=1;

{(Subscript[x, min]),(Subscript[x, max])}={-0.1,6};
{(Subscript[y, min]),(Subscript[y, max])}={-0.1,6};

f[x_,y_]:=a x - b x y

g[x_,y_]:=- c y +d x y

Vector field

V={f[x,y],g[x,y]}

Fixed Points & Nullclines

fp=Solve[{f[(Subscript[x, 1]),(Subscript[y, 1])]==0,g[(Subscript[x, 1]),(Subscript[y, 1])]==0},{(Subscript[x, 1]),(Subscript[y, 1])}]

fp1=Sort[fp[[1]]];fp2=Sort[fp[[2]]];

{(Subscript[x, 1]),(Subscript[y, 1])}={Extract[fp1,{1}][[2]],Extract[fp1,{2}][[2]]};
fixedpoint1=Show[Graphics[{PointSize[0.025],Hue[0.33],Point[{(Subscript[x, 1]),(Subscript[y, 1])}]},PlotRange->{{(Subscript[x, min]),(Subscript[x, max])},{(Subscript[y, min]),(Subscript[y, max])}}]];

{(Subscript[x, 2]),(Subscript[y, 2])}={Extract[fp2,{1}][[2]],Extract[fp2,{2}][[2]]};
fixedpoint2=Show[Graphics[{PointSize[0.025],Hue[0.33],Point[{(Subscript[x, 2]),(Subscript[y, 2])}]},PlotRange->{{(Subscript[x, min]),(Subscript[x, max])},{(Subscript[y, min]),(Subscript[y, max])}}]];

nullclines=ContourPlot[{f[x,y]==0,g[x,y]==0},{x,(Subscript[x, min]),(Subscript[x, max])},{y,(Subscript[y, min]),(Subscript[y, max])},ContourStyle->{{Green,Thickness[0.005]}}];

Show[nullclines,fixedpoint1,fixedpoint2]

Jacobian

a11=Simplify[D[f[x,y],x]]

a12=Simplify[D[f[x,y],y]]

a21=Simplify[D[g[x,y],x]]

a22=Simplify[D[g[x,y],y]]

J={{a11,a12},{a21,a22}}

MatrixForm[J]

Acceleration

γ=J . V

Fixed Points Stability - Eigenvalues

Eigenvalues[J]/.{x-> (Subscript[x, 1]),y->(Subscript[y, 1])}

Eigenvalues[J]/.{x-> (Subscript[x, 2]),y->(Subscript[y, 2])}

Phase Portrait

solution=NDSolve[{x'[t]==f[x[t],y[t]],x[0]==.1,

y'[t]==g[x[t],y[t]],y[0]==.1},{x,y},

{t,0,100},Method->"ExplicitRungeKutta", MaxSteps->Infinity,StartingStepSize->0.001];phaseplot=ParametricPlot[Evaluate[{x[t],y[t]}/.solution],{t,80,100},PlotPoints->1000,PlotRange->{{(Subscript[x, min]),(Subscript[x, max])},{(Subscript[y, min]),(Subscript[y, max])}},AxesLabel->{"X","Y"},PlotStyle->{{Red,Thickness[0.005]}},AspectRatio->1,Frame->True];

Show[phaseplot,fixedpoint1,fixedpoint2]

plotX=Plot[Evaluate[x[t]/.solution],{t,50,100},PlotRange->{(Subscript[x, min]),(Subscript[x, max])},PlotStyle->{RGBColor[0,0,1]}]

plotY=Plot[Evaluate[y[t]/.solution],{t,50,100},PlotRange->{(Subscript[y, min]),(Subscript[y, max])},PlotStyle->{RGBColor[0,1,0]}]

Show[plotX,plotY]

Flow Curvature Manifold

ϕ=FullSimplify[Det[{V,γ}]]

flowmanifold=ContourPlot[{ϕ==0},{x,(Subscript[x, min]),(Subscript[x, max])},{y,(Subscript[y, min]),(Subscript[y, max])},ContourStyle->{{Blue,Thickness[0.005]}},AspectRatio->1,Frame->True]

Flow Curvature Invariance

Normal Vector

η={D[ϕ,x],D[ϕ,y]}

Invariance

Ψ=FullSimplify[V . η]

invariantpart=ContourPlot[{Ψ==0},{x,(Subscript[x, min]),(Subscript[x, max])},{y,(Subscript[y, min]),(Subscript[y, max])},ContourStyle->{{Magenta,Thickness[0.005],Dashing[{.025}]}},Frame->True,AspectRatio->1]

Show[phaseplot,fixedpoint2,flowmanifold,invariantpart,Frame->True,ImageSize->{600,600} ]